Sub TEST3()
Range("A1").Select '元データを選択
ActiveSheet.Shapes.AddChart2.Select 'グラフを作成
ActiveChart.ChartType = xlColumnClustered '集合縦棒
End Sub
では、VBAコードを実行してみます。
棒グラフを作成
棒グラフを作成できました。
列方向のデータを系列にする
「列方向のデータ」を系列にしてみます。
「列方向のデータ」を系列にするには、「.PlotBy = xlColumns」とします。
Sub TEST4()
'元データの「列方向」のデータを「系列」にする
ActiveSheet.ChartObjects(1).Chart.PlotBy = xlColumns
End Sub
では、VBAコードを実行してみます。
「列方向」のデータを系列にする
「列方向」のデータを系列にできました。
「合計」の系列を「2軸」にする
「合計」の系列を「2軸」にしてみます。
先ほど紹介した内容です。
4つ目の系列なので、「.SeriesCollection(4)」を使います。
2軸に設定するので、「.AxisGroup = 2」です。
Sub TEST5()
'「4つ目」の系列
With ActiveSheet.ChartObjects(1).Chart.SeriesCollection(4)
.AxisGroup = 2 '第2軸にする
End With
End Sub
では、実行してみます。
「合計」の系列を「2軸」に設定
「合計」の系列を「2軸」に設定できました。
「合計」の系列を「折れ線」に変更する
グラフが被っていて見づらいので、「合計」の系列を「折れ線」に変更します。
「.ChartType = xlLine」で折れ線に変更できます。
Sub TEST6()
'「4つ目」の系列
With ActiveSheet.ChartObjects(1).Chart.SeriesCollection(4)
.ChartType = xlLine '折れ線に変更する
End With
End Sub
では、VBAコードを実行してみます。
「合計」の系列を「折れ線」に変更
「合計」の系列を「折れ線」に変更できました。
ラベルを設定する
軸ラベルを設定して、どの数値軸を確認すればいいかをわかりやすくします。
「縦軸の第1軸」は「.Axes(xlValue, 1)」のオブジェクトを使います。
「縦軸の第2軸」は「.Axes(xlValue, 2)」となります。
Sub TEST7()
'縦軸の第1軸
With ActiveSheet.ChartObjects(1).Chart.Axes(xlValue, 1)
.HasTitle = True '軸ラベルを表示
.AxisTitle.Text = "売上"
End With
'縦軸の第2軸
With ActiveSheet.ChartObjects(1).Chart.Axes(xlValue, 2)
.HasTitle = True '軸ラベルを表示
.AxisTitle.Text = "合計"
End With
End Sub
Sub TEST8()
Range("A1").Select '元データを選択
ActiveSheet.Shapes.AddChart2.Select 'グラフを作成'アクティブシートの1つ目のグラフのチャート
With ActiveChart
.ChartType = xlColumnClustered '集合縦棒
.PlotBy = xlColumns '「列方向」のデータを「系列」にする'「4つ目」の系列
With .SeriesCollection(4)
.AxisGroup = 2 '第2軸にする
.ChartType = xlLine '折れ線に変更する
End With
'縦軸の第1軸
With .Axes(xlValue, 1)
.HasTitle = True '軸ラベルを表示
.AxisTitle.Text = "売上"
End With
'縦軸の第2軸
With .Axes(xlValue, 2)
.HasTitle = True '軸ラベルを表示
.AxisTitle.Text = "合計"
End With
End With
End Sub