－ちょっと使えるネタを紹介－
Excel VBAで、条件一致した値を抽出する方法として、「ForとIfを組み合わせる」方法と「オートフィルタ」を使う使う方法があります。「オートフィルタ」を使った方がシンプルで、複数条件に一致した値の抽出も簡単にできます。値の抽出は実務ではよく使うのでマスターしていきましょう。
この記事では、条件一致した値を抽出する方法について、ご紹介します。
実務では、よくやる作業ですね。
やり方として、2つの方法でやってみます。
断然、「オートフィルタ」を使って抽出する方が簡単です。
複数条件に一致した値の抽出も簡単にできます。
条件に一致した値の抽出は実務でよく使うのでマスターしていきましょう。
では、条件一致した値を抽出する方法について、解説していきます。
この記事で紹介すること
目次から見たい項目へ移動すると便利ですよ。
目次
ForとIfを組み合わせて条件一致した値を抽出してみます。
「ForとIfを組み合わせて」1つの条件一致で抽出してます。
手順としては、
という感じです。
Sub TEST1()
Dim N
For i = 2 To 10
'A列が「B」の場合
If Worksheets("Sheet2").Cells(i, "A") = "B" Then
'Sheet1の最終行を取得
N = Worksheets("Sheet1").Cells(Rows.Count, "A").End(xlUp).Row
'一致したデータを最終行の1行下にコピー
Worksheets("Sheet2").Cells(i, "A").Resize(, 3).Copy Worksheets("Sheet1").Cells(N + 1, "A")
End If
Next
End Sub
ちょっと長いので、「With」でくくっておきます。
Sub TEST2()
Dim N
'「With」でくくる
With Worksheets("Sheet1")
For i = 2 To 10
'A列が「B」の場合
If Worksheets("Sheet2").Cells(i, "A") = "B" Then
'Sheet1の最終行を取得
N = .Cells(Rows.Count, "A").End(xlUp).Row
'一致したデータを最終行の1行下にコピー
Worksheets("Sheet2").Cells(i, "A").Resize(, 3).Copy .Cells(N + 1, "A")
End If
Next
End With
End Sub
表を用意しておきます。
Sheet1が抽出元シートで、Sheet2が抽出先のシートです。
では、VBAコードを実行してみます。
A列が「B」の値を抽出します。
では、結果をみてみます。
A列が「B」の値を抽出を抽出できました。
複数の条件一致する値を抽出してみます。
Ifの条件を追加します。
Sub TEST3()
Dim N
With Worksheets("Sheet1")
For i = 2 To 10
'A列が「B」の場合
If Worksheets("Sheet2").Cells(i, "A") = "B" Then
'B列が「名古屋」の場合
If Worksheets("Sheet2").Cells(i, "B") = "名古屋" Then
'最終行を取得
N = .Cells(Rows.Count, "A").End(xlUp).Row
'一致したデータを最終行の1行下にコピー
Worksheets("Sheet2").Cells(i, "A").Resize(, 3).Copy .Cells(N + 1, "A")
End If
End If
Next
End With
End Sub
表を用意します。
表をループしてA列が「B」で、B列が「名古屋」のセルをコピーしていきます。
A列が「B」で、B列が「名古屋」を抽出できます。
A列が「B」で、B列が「名古屋」を抽出できました。
同じ要領で、Ifの条件を変更することでできます。
Sub TEST4()
Dim N
With Worksheets("Sheet1")
For i = 2 To 10
'B列が「名古屋」の場合
If Worksheets("Sheet2").Cells(i, "B") = "名古屋" Then
'C列が「500以上」の場合
If Worksheets("Sheet2").Cells(i, "C") >= 500 Then
'最終行を取得
N = .Cells(Rows.Count, "A").End(xlUp).Row
'一致したデータを最終行の1行下にコピー
Worksheets("Sheet2").Cells(i, "A").Resize(, 3).Copy .Cells(N + 1, "A")
End If
End If
Next
End With
End Sub
表を用意します。
表をループしてB列が「名古屋」で、C列が「500以上」をコピーしていきます。
B列が「名古屋」で、C列が「500以上」を抽出できます。
B列が「名古屋」で、C列が「500以上」を抽出できました。
セルの値を条件にして抽出することもできます。
Sub TEST5()
Dim N
With Worksheets("Sheet1")
For i = 2 To 10
'B列が「名古屋」の場合
If Worksheets("Sheet2").Cells(i, "B") = .Range("E2") Then
'C列が「500以上」の場合
If Worksheets("Sheet2").Cells(i, "C") >= .Range("F2") Then
'最終行を取得
N = .Cells(Rows.Count, "A").End(xlUp).Row
'一致したデータを最終行の1行下にコピー
Worksheets("Sheet2").Cells(i, "A").Resize(, 3).Copy .Cells(N + 1, "A")
End If
End If
Next
End With
End Sub
条件をセルに入力します。
B列が「名古屋」で、C列が「500以上」を抽出します。
これで、B列が「名古屋」で、C列が「500以上」を抽出できます。
B列が「名古屋」で、C列が「500以上」を抽出できました。
次は、「オートフィルタ」を使って条件一致する値を抽出してみます。
まずは、「1つ」の条件一致で抽出
手順としては、
という感じです。
Sub TEST6()
'A列を「B」でフィルタ
Worksheets("Sheet2").Range("A1").AutoFilter 1, "B"
'フィルタ結果をSheet1にコピー
Worksheets("Sheet2").Range("A1").CurrentRegion.Copy Worksheets("Sheet1").Range("A1")
'オートフィルタを解除
Worksheets("Sheet2").Range("A1").AutoFilter
End Sub
表を用意します。
A列を「B」でフィルタして表全体をコピーします。
オートフィルタを使って抽出できます。
オートフィルタを使って抽出できました。
表全体ではなく、表の「見出しを除く」値をコピーする方法でやってみます。
見出しはコピーしたくない場合に使えます。
「Resize」と「Offset」を組み合わせて使います。
Sub TEST7()
'A列を「B」でフィルタ
Worksheets("Sheet2").Range("A1").AutoFilter 1, "B"
'フィルタ結果の「見出しを除くセル範囲」をSheet1にコピー
With Worksheets("Sheet2").Range("A1").CurrentRegion
.Resize(.Rows.Count - 1).Offset(1, 0).Copy Worksheets("Sheet1").Range("A2")
End With
'オートフィルタを解除
Worksheets("Sheet2").Range("A1").AutoFilter
End Sub
表を用意します。
「見出しを除く」値をコピーします。
「Resize」と「Offset」を組み合わせるのがポイントです。
オートフィルタを使って抽出できます。
オートフィルタを使って抽出できました。
「オートフィルタ」を使えば、「複数の条件一致」で抽出するのも簡単です。
A列が「B」で、B列が「名古屋」を抽出してみます。
フィルタする列を増やしてあげればできます。
Sub TEST8()
'A列を「B」でフィルタ
Worksheets("Sheet2").Range("A1").AutoFilter 1, "B"
'B列を「名古屋」でフィルタ
Worksheets("Sheet2").Range("A1").AutoFilter 2, "名古屋"
'フィルタ結果の「見出しを除くセル範囲」をSheet1にコピー
With Worksheets("Sheet2").Range("A1").CurrentRegion
.Resize(.Rows.Count - 1).Offset(1, 0).Copy Worksheets("Sheet1").Range("A2")
End With
'オートフィルタを解除
Worksheets("Sheet2").Range("A1").AutoFilter
End Sub
表を用意します。
A列が「B」で、B列が「名古屋」をフィルタしてコピーします。
A列が「B」で、B列が「名古屋」を抽出できます。
A列が「B」で、B列が「名古屋」を抽出できました。
B列が「名古屋」で、C列が「500以上」を抽出
Sub TEST9()
'B列を「名古屋」でフィルタ
Worksheets("Sheet2").Range("A1").AutoFilter 2, "名古屋"
'C列を「500以上」でフィルタ
Worksheets("Sheet2").Range("A1").AutoFilter 3, ">=500"
'フィルタ結果の「見出しを除くセル範囲」をSheet1にコピー
With Worksheets("Sheet2").Range("A1").CurrentRegion
.Resize(.Rows.Count - 1).Offset(1, 0).Copy Worksheets("Sheet1").Range("A2")
End With
'オートフィルタを解除
Worksheets("Sheet2").Range("A1").AutoFilter
End Sub
表を用意します。
B列が「名古屋」で、C列が「500以上」をフィルタしてコピーします。
B列が「名古屋」で、C列が「500以上」を抽出できます。
B列が「名古屋」で、C列が「500以上」を抽出できました。
「オートフィルタ」を使う方法で、「セルの値」を条件にして抽出してみます。
B列が「名古屋」で、C列が「500以上」します。
Sub TEST10()
'B列を「名古屋」でフィルタ
Worksheets("Sheet2").Range("A1").AutoFilter 2, Worksheets("Sheet1").Range("E2")
'C列を「500以上」でフィルタ
Worksheets("Sheet2").Range("A1").AutoFilter 3, Worksheets("Sheet1").Range("F2")
'フィルタ結果の「見出しを除くセル範囲」をSheet1にコピー
With Worksheets("Sheet2").Range("A1").CurrentRegion
.Resize(.Rows.Count - 1).Offset(1, 0).Copy Worksheets("Sheet1").Range("A2")
End With
'オートフィルタを解除
Worksheets("Sheet2").Range("A1").AutoFilter
End Sub
セルに条件を入力します。
B列が「名古屋」で、C列が「500以上」をフィルタしてコピーします。
これで、B列が「名古屋」で、C列が「500以上」の値を抽出できます。
抽出できました。
オートフィルタ便利です。
この記事では、条件一致した値を抽出する方法について、ご紹介しました。
やり方として、2つを紹介しました。
断然、「オートフィルタ」を使って抽出する方が簡単です。
複数条件に一致した値の抽出も簡単にできます。
参考になればと思います。最後までご覧くださいまして、ありがとうございました。
関連する記事から探す
カテゴリから見たい項目を探すと便利ですよ。
↓キーワードを入力する