大体でIT

－ちょっと使えるネタを紹介－

HOME >  Excel VBA >  ワークシート関数や数式を使う
大体でIT

Excel VBAで、SumIfs関数を使って「複数条件」に一致するセルの合計値を算出する方法について、ご紹介します。「数式を埋め込む」方法を使うと感覚的にわかりやすいです。算出した結果をVBAの中で使うのであれば「WorksheetFunction」を使う方法が便利です。

はじめに

この記事では、SumIfs関数を使って、「複数条件」に一致するセルの合計を計算する方法について、ご紹介します。

SumIfs関数を使う方法として、「WorksheetFunction」を使う方法と「数式を埋め込む」方法があります。

「数式を埋め込む」方法の方が感覚的にわかりやすいです。

セルに入力して使うなら、「数式を埋め込む」方法が便利です。

算出した結果をVBAの中で使うのであれば、「WorksheetFunction」を使うといいです。

SumIfs関数は、「比較演算子」や「ワイルドカード」が使えますので、うまく使っていきましょう。

では、SumIfs関数を使って「複数条件」に一致するセルの合計値を算出する方法について、解説していきます。

この記事で紹介すること

  • VBAでSumIfs関数を使う方法

本記事の内容を動画でまとめています

こちらの記事も参考になります

目次から見たい項目へ移動すると便利ですよ。

目次

VBAコードまとめ

SumIfs関数を使って「複数条件」に一致したセルを算出するVBAコードについて、まとめています。

VBAコードだけ確認したい場合に、ご活用ください。

'■「WorksheetFunction」で、SumIfs関数を使う

'SumIfs関数を使う
Range("E2") = WorksheetFunction.SumIfs(Range("C:C"), Range("A:A"), "B", Range("B:B"), "大阪")
'比較演算子を使う
Range("D2") = WorksheetFunction.SumIfs(Range("B:B"), Range("A:A"), ">=2021/8/1", Range("A:A"), "<=2021/9/3")
'ワイルドカードを使う
Range("E2") = WorksheetFunction.SumIfs(Range("C:C"), Range("A:A"), "B*", Range("B:B"), "大阪")
'変数を使う
a = "B"
b = "大阪"
Range("E2") = WorksheetFunction.SumIfs(Range("C:C"), Range("A:A"), a, Range("B:B"), b)
'セルの値を使う
Range("F4") = WorksheetFunction.SumIfs(Range("C:C"), Range("A:A"), Range("F1"), Range("B:B"), Range("F2"))

'■「数式を埋め込んで」SumIfs関数を使う

'SumIf関数を使う
Range("E2") = "=SUMIFS(C:C,A:A,""B"",B:B,""大阪"")"
'比較演算子を使う
Range("D2") = "=SUMIFS(B:B,A:A,"">=2021/8/1"",A:A,""<=2021/9/3"")"
'ワイルドカードを使う
Range("E2") = "=SUMIFS(C:C,A:A,""B*"",B:B,""大阪"")"
'変数を使う
a = """B"""
b = """大阪"""
Range("E2") = "=SUMIFS(C:C,A:A," & a & ",B:B," & b & ")"
'セルの値を使う
Range("F4") = "=SUMIFS(C:C,A:A,F1,B:B,F2)"

では、解説していきます。

WorksheetFunctionでSumIfs関数を使う

「WorksheetFunction」でSumIfs関数を使ってみます。

SumIfs関数に入力する引数　

SumIfs関数に入力する引数は、数式として使う場合と同じで、次のようになります。

'SumIfs関数を使う
a = WorksheetFunction.SumIfs(合計範囲, 範囲1, 条件1, 範囲2, 条件2)

では、実際にやってみます。

SumIfs関数を使ってみる　

「WorksheetFunction」を使ってSumIfs関数を使うには、次のように入力します。

商品が「B」で、支店が「大阪」の価格を合計します。

Sub TEST1()
    
    '商品が「B」で、支店が「大阪」の価格を合計
    Range("E2") = WorksheetFunction.SumIfs(Range("C:C"), Range("A:A"), "B", Range("B:B"), "大阪")
    
End Sub

表を用意しておきます。

表を用意

表を用意

では、VBAコードを実行してみます。

「"B"」と「"大阪"」に一致するセルの合計値

「

「"B"」と「"大阪"」に一致するセルの合計値を算出できました。

比較演算子を使う

SumIfs関数で「比較演算子」を使ってみます。

比較演算子には次の種類があります。

  • 「">値"」 ：値より大きい
  • 「"<値"」 ：値より小さい
  • 「">=値"」：値以上
  • 「"<=値"」：値以下
  • 「"<>値"」：値以外
  • 「""」　　：空白
  • 「"<>"」　：空白以外

比較演算子を使って、「2021/8/1」～「2021/9/3」の売上を合計してみます。

Sub TEST2()
    
    '「2021/8/1」～「2021/9/3」の売上を合計
    Range("D2") = WorksheetFunction.SumIfs(Range("B:B"), Range("A:A"), ">=2021/8/1", Range("A:A"), "<=2021/9/3")
    
End Sub

表を用意しておきます。

表を用意

表を用意

では、VBAコードを実行してみます。

「比較演算子」を使う

「比較演算子」を使う

「比較演算子」を使って、一致するセルの合計値を算出できました。

ワイルドカードを使う

SumIfs関数でワイルドカードを使ってみます。

ワイルドカードには、次の2つがあります。

  • 「*」：なんでもいい
  • 「?」：なんでもいい。ただし1文字。

ワイルドカードを使って、商品が「Bを含む」値で、支店が「大阪」の価格を合計してみます。

Sub TEST3()
    
    '商品が「Bを含む」値で、支店が「大阪」の価格を合計
    Range("E2") = WorksheetFunction.SumIfs(Range("C:C"), Range("A:A"), "B*", Range("B:B"), "大阪")
    
End Sub

表を用意しておきます。

表を用意

表を用意

では、VBAコードを実行してみます。

「ワイルドカード」を使う

「ワイルドカード」を使う

「ワイルドカード」を使って、合計値を算出できました。

変数を使う

SumIfs関数で、変数を使ってみます。

Sub TEST4()
    
    a = "B"
    b = "大阪"
    
    '商品が「B」で、支店が「大阪」の価格を合計
    Range("E2") = WorksheetFunction.SumIfs(Range("C:C"), Range("A:A"), a, Range("B:B"), b)
    
End Sub

表を用意しておきます。

表を用意

表を用意

では、VBAコードを実行してみます。

「変数」を使う

「変数」を使う

「変数」を使って、SumIfs関数で合計値を算出できました。

セルの値を使う

SumIfs関数に、セルの値を使って条件を指定することもできます。

Sub TEST5()
    
    '商品が「B」で、支店が「大阪」の価格を合計
    Range("F4") = WorksheetFunction.SumIfs(Range("C:C"), Range("A:A"), Range("F1"), Range("B:B"), Range("F2"))
    
End Sub

表を用意しておきます。

表を用意

表を用意

では、VBAコードを実行してみます。

「セルの値」を使う

「セルの値」を使う

「セルの値」を使って条件を指定して、合計値を算出できました。

クロス集計表を作成する

SumIfs関数は、「クロス集計表」を作成する際にかなり便利に使えます。

Sub TEST6()
    
    '「商品」をループ
    For i = 1 To 3
        '「支店」をループ
        For j = 1 To 3
            With Range("E1")
                '「商品」と「支店」が一致する価格の合計
                .Offset(i, j) = WorksheetFunction.SumIfs(Range("C:C"), Range("A:A"), .Offset(i, 0), Range("B:B"), .Offset(0, j))
            End With
        Next
    Next
    
End Sub

ポイントは「行と列の条件」をループして、合計値を入力するところです。

表を用意しておきます。

表を用意

表を用意

では、VBAコードを実行してみます。

クロス集計表を作成する

クロス集計表を作成する

「クロス集計表」を作成できました。

数式を埋め込んでSumIfs関数を使う

SumIfs関数をVBAで使うもう一つの方法が、「数式を埋め込む」方法です。

数式を埋め込んでSumifs関数を使う

「数式を埋め込んで」Sumifs関数を使ってみます。

セルに入力する数式を「文字列」としてセルに入力することで、使うことができます。

Sub TEST7()
    
    '商品が「B」で、支店が「大阪」の価格を合計
    Range("E2") = "=SUMIFS(C:C,A:A,""B"",B:B,""大阪"")"
    Range("E2").Value = Range("E2").Value '値に変換
    
End Sub

ポイントは、「"B"」は、「""B""」のように「""」で囲ってあげることです。

表を用意しておきます。

表を用意

表を用意

では、VBAコードを実行してみます。

「"B"」と「"大阪"」に一致するセルの合計値

「

「"B"」と「"大阪"」に一致するセルの合計値を算出できました。

セルに数式を入力してコピーして使う

数式を埋め込む際は、一度セルに数式を入力して、「数式をコピー」して使うと簡単です。

セルに数式を入力してコピーして使う

入力が正しいことを確認できれば、あとは数式をコピーします。

比較演算子を使う

「比較演算子」を使ったSumIfs関数の数式を埋め込んでみます。

「2021/8/1」～「2021/9/3」の売上を合計してみます。

Sub TEST8()
    
    '「2021/8/1」～「2021/9/3」の売上を合計
    Range("D2") = "=SUMIFS(B:B,A:A,"">=2021/8/1"",A:A,""<=2021/9/3"")"
    Range("D2").Value = Range("D2").Value '値に変換
    
End Sub

表を用意しておきます。

表を用意

表を用意

では、VBAコードを実行してみます。

「比較演算子」を使う

「比較演算子」を使う

「比較演算子」を使って、条件に一致するセルの合計値を算出できました。

ワイルドカードを使う

SumIfs関数でワイルドカードを使って、数式を埋め込んでみます。

商品が「Bを含む」値で、支店が「大阪」の価格を合計します。

Sub TEST9()
    
    '商品が「Bを含む」値で、支店が「大阪」の価格を合計
    Range("E2") = "=SUMIFS(C:C,A:A,""B*"",B:B,""大阪"")"
    Range("E2").Value = Range("E2").Value '値に変換
        
End Sub

表を用意しておきます。

表を用意

表を用意

では、VBAコードを実行してみます。

「ワイルドカード」を使う

「ワイルドカード」を使う

「ワイルドカード」を使って、条件一致のセルの合計値を算出できました。

変数を使う

SumIfs関数を埋め込む方法で、「変数」を使ってみます。

ポイントは、変数に入力する際に「a = """B"""」のように「""」で囲うことです。

Sub TEST10()
    
    a = """B""" '商品が「B」
    b = """大阪""" '支店が「大阪」
    
    '商品が「B」で、支店が「大阪」の価格を合計
    Range("E2") = "=SUMIFS(C:C,A:A," & a & ",B:B," & b & ")"
    Range("E2").Value = Range("E2").Value '値に変換
    
End Sub

表を用意しておきます。

表を用意

表を用意

では、VBAコードを実行してみます。

「変数」を使う

「変数」を使う

「変数」を使って、条件一致の合計値を算出できました。

セルの値を使う

セルの値を条件とするSumIfs関数を埋め込んでみます。

Sub TEST11()
    
    '商品が「B」で、支店が「大阪」の価格を合計
    Range("F4") = "=SUMIFS(C:C,A:A,F1,B:B,F2)"
    Range("F4").Value = Range("F4").Value '値に変換
    
End Sub

条件をセルに入力しておきます。

条件をセルに入力

表を用意

では、VBAコードを実行してみます。

「セルの値」を使う

「セルの値」を使う

「セルの値」を条件としてSumIfs関数で、条件一致の合計値を算出できました。

クロス集計表を作成する

SumIfs関数を埋め込むと、「クロス集計表」が簡単に作成できます。

Sub TEST12()
    
    '「商品」と「価格」が一致する価格の合計
    Range("F2:H4") = "=SUMIFS($C:$C,$A:$A,$E2,$B:$B,F$1)"
    Range("F2:H4").Value = Range("F2:H4").Value '値に変換
    
End Sub

ポイントは、「絶対参照」にするところと「相対参照」にするセル範囲を、うまく設定することです。

セルに貼り付けた際に、セルから条件を取得できるようにします。

表を用意しておきます。

表を用意

表を用意

では、VBAコードを実行してみます。

クロス集計表を作成する

クロス集計表を作成する

クロス集計表を作成できました。

クロス集計表を作成するだけなら、1行で書けるのでかなり便利です。

おわりに

この記事では、SumIfs関数を使って、「複数条件」に一致するセルの合計を計算する方法について、ご紹介しました。

SumIfs関数を使う方法として、「WorksheetFunction」を使う方法と「数式を埋め込む」方法があります。

「数式を埋め込む」方法の方が感覚的にわかりやすいです。

セルに入力して使うなら、「数式を埋め込む」方法が便利です。

算出した結果をVBAの中で使うのであれば、「WorksheetFunction」を使うといいです。

SumIfs関数は、「比較演算子」や「ワイルドカード」が使えますので、うまく使っていきましょう。

参考になればと思います。最後までご覧くださいまして、ありがとうございました。

関連する記事から探す

カテゴリから探す

カテゴリから見たい項目を探すと便利ですよ。

サイト内を検索する

↓キーワードを入力する

アーカイブから探す